В данной статье приводится полностью рабочий скрипт, который умеет создавать ярлык на рабочем столе у пользователя, а также запускать блокнотом текстовый файл с важной информацией для пользователя...
Данный скрипт полностью рабочий и может применяться совместно с групповой политикой (при этом скрипт легко отрабатывает от имени обычного пользователя домена без повышения прав).
Суть моего творения в корне лежит в идее массового переезда сотрудников одного из наших филиалов на новый сервер. Так как за ночь я перенёс все их сетевые шары, то мне не очень хотелось после бессонной ночи переправлять у пятидесяти пользователей ссылки на новые шары. Поэтому я заранее подготовился, а именно - с помощью групповой политики я принудительно у всех пользователей филиала выкатил ярлык на сетевую папку, в которой лежали новые ярлыки на новые шары. Ну а чтобы не было глупых вопросов по поводу нерабочих старых ярлыков, в скрипте я предусмотрел запуск текстового файла с важной информацией для сотрудников о их переезде на новый сервер. Таким образом я убил двух зайцев одним выстрелом!
Итак сам скрипт AddShotCut.vbs (я надеюсь, что он кому-нибудь пригодится):

' Создание ярлыка программы. VBScript
' Объявляем переменные
Dim WSHShell
Dim MyShortcut, MyDesktop, DesktopPath
Dim FSO, FileName
Dim Windows
SET WSHShell = WScript.CreateObject("WScript.Shell")
' Узнаём путь к папке Windows
Windows=wshShell.ExpandEnvironmentStrings ("%SystemRoot%")
' Узнаем путь к Рабочему столу
DesktopPath = WSHShell.SpecialFolders("Desktop")
'Создаем объект FileSystemObject
Set FSO = WScript.CreateObject("Scripting.FileSystemObject")
FileName = DesktopPath + "\Новые ярлыки.lnk"
' Проверяем наличие ярлыка на рабочем столе
' Если его нету, то создаём новый и запускаем блокнот с новыми инструкциями
if  not(FSO.FileExists(FileName))  Then
' Создаем ярлык:
   Set MyShortcut = WSHShell.CreateShortcut(DesktopPath + "\Новые ярлыки.lnk")
' Задаем свойства для ярлыка:
' Запускаемый файл
   MyShortcut.TargetPath = WSHShell.ExpandEnvironmentStrings("\\FileServer\shortcut")
' Директория запускаемого файла
   MyShortcut.WorkingDirectory = WSHShell.ExpandEnvironmentStrings("")
' Клавиши для быстрого вызова программы
   MyShortcut.HotKey = ("CTRL+ALT+N")
' Тип окна запускаемого файла
   MyShortcut.WindowStyle = 4
' Иконка, используемая для ярлыка
   MyShortcut.IconLocation = WSHShell.ExpandEnvironmentStrings("\\FileServer\shortcut")
' Сохраняем изменения свойств ярлыка
   MyShortcut.Save()
' Запускаем блокнот  
   notepad = windows+"\NotePad.exe \\FileServer\shortcut\новое.txt"
   WSHShell.Run (notepad)
end if
Set WSHShell = Nothing
Set FSO = Nothing
' Готово! К бабке можно не ходить...

Ну вот пожалуй и всё на этом... Удачи!
Жизнь алмина должна быть проще!